Counts the number of cells within a range that meet the given criteria.

Syntax

COUNTIF(range,criteria)

Range is one or more cells to count, including numbers or names, arrays, or references that contain numbers. Blank and text values are ignored.

Criteria is the criteria in the form of a number, expression, cell reference, or text that defines which cells will be counted. For example, criteria can be expressed as 32, "32", ">32", "apples", or B4.

Remark

Example 1: Common COUNTIF formulas

The example may be easier to understand if you copy it to a blank worksheet.

How to copy an example

  1. Create a blank workbook or worksheet.
  2. Select the example in the Help topic.

    Note Do not select the row or column headers.

    selecting an example from helpSelecting an example from Help

  3. Press CTRL+C.
  4. In the worksheet, select cell A1, and press CTRL+V.
  5. To switch between viewing the results and viewing the formulas that return the results, press CTRL+` (grave accent), or on the Formulas tab, in the Formula Auditing group, click the Show Formulas button.
1
2
3
4
5
A B
Data Data
apples 32
oranges 54
peaches 75
apples 86
Formula Description (result)
=COUNTIF(A2:A5,"apples") Number of cells with apples in the first column above (2)
=COUNTIF(A2:A5,A4) Number of cells with peaches in the first column above (1)
=COUNTIF(A2:A5,A3)+COUNTIF(A2:A5,A2) Number of cells with oranges and apples in the first column above (3)
=COUNTIF(B2:B5,">55") Number of cells with a value greater than 55 in the second column above (2)
=COUNTIF(B2:B5,"<>"&B4) Number of cells with a value not equal to 75 in the second column above (3)
=COUNTIF(B2:B5,">=32")-COUNTIF(B2:B5,">85") Number of cells with a value greater than or equal to 32 and less than or equal to 85 in the second column above (3)

Example 2: COUNTIF formulas using wildcard characters and handling blank values

The example may be easier to understand if you copy it to a blank worksheet.

How to copy an example

  1. Create a blank workbook or worksheet.
  2. Select the example in the Help topic.

    Note Do not select the row or column headers.

    selecting an example from helpSelecting an example from Help

  3. Press CTRL+C.
  4. In the worksheet, select cell A1, and press CTRL+V.
  5. To switch between viewing the results and viewing the formulas that return the results, press CTRL+` (grave accent), or on the Formulas tab, in the Formula Auditing group, click the Show Formulas button.
1
2
3
4
5
6
7
A B
Data Data
apples Yes
oranges NO
peaches No
apples YeS
Formula Description (result)
=COUNTIF(A2:A7,"*es") Number of cells ending with the letters "es" in the first column above (4)
=COUNTIF(A2:A7,"?????es") Number of cells ending with the letters "les" and having exactly 7 letters in the first column above (2)
=COUNTIF(A2:A7,"*") Number of cells containing text in the first column above (4)
=COUNTIF(A2:A7,"<>"&"*") Number of cells not containing text in the first column above (2)
=COUNTIF(B2:B7,"No") / ROWS(B2:B7) The average number of No votes including blank cells in the second column above formatted as a percentage with no decimal places (33%)
=COUNTIF(B2:B7,"Yes") / (ROWS(B2:B7) -COUNTIF(B2:B7, "<>"&"*")) The average number of Yes votes excluding blank cells in the second column above formatted as a percentage with no decimal places (50%)

Note You can view the number as a percentage. Select the cell, and then on the Sheet tab in the Number group, click Percentage Style button image.

See also: