SE (Função SE) - Excel - Microsoft Office

Este artigo descreve a sintaxe da fórmula e o uso da função SE no Microsoft Excel.

Descrição

A função SE retornará um valor se uma condição que você especificou for avaliada como VERDADEIRO e um outro valor se essa condição for avaliada como FALSO. Por exemplo, a fórmula =SE(A1>10,"Mais que 10","10 ou menos") retornará "Mais que 10" se A1 for maior que 10 e "10 ou menos" se A1 for menor que ou igual a 10.

Sintaxe

SE(teste_lógico, [valor_se_verdadeiro], [valor_se_falso])

A sintaxe da função SE tem os seguintes ARGUMENTOS .

Teste_lógico Obrigatório. Qualquer valor ou expressão que possa ser avaliado como VERDADEIRO ou FALSO. Por exemplo, A10=100 é uma expressão lógica; se o valor da célula A10 for igual a 100, a expressão será considerada VERDADEIRO. Caso contrário, a expressão será considerada FALSO. Esse argumento pode usar qualquer operador de cálculo de comparação.
Valor_se_verdadeiro Opcional. O valor que você deseja que seja retornado se o argumento teste_lógico for considerado VERDADEIRO. Por exemplo, se o valor desse argumento for a cadeia de texto "Dentro do orçamento" e o argumento teste_lógico for considerado VERDADEIRO, a função SE retornará o texto "Dentro do orçamento". Se teste_lógico for considerado VERDADEIRO e o argumento valor_se_verdadeiro for omitido (ou seja, há apenas uma vírgula depois do argumento teste_lógico), a função SE retornará 0 (zero). Para mostrar a palavra VERDADEIRO, use o valor lógico VERDADEIRO para o argumento valor_se_verdadeiro.
Valor_se_falso Opcional. O valor que você quer que seja retornado se o argumento teste_lógico for avaliado como FALSO. Por exemplo, se o valor desse argumento for a cadeia de texto "Acima do orçamento", e o argumento teste_lógico for avaliado como FALSO, a função SE retornará o texto "Acima do orçamento". Se teste_lógico for avaliado como FALSO, e o argumento valor_se_falso for omitido (ou seja, não há vírgula depois do argumento valor_se_verdadeiro), a função SE retornará o valor lógico FALSO. Se teste_lógico for avaliado como FALSO, e o valor do argumento valor_se_falso estiver em branco (ou seja, se houver apenas uma vírgula após o argumento valor_se_verdadeiro), a função SE retornará o valor 0 (zero).

Comentários

Até 64 funções SE podem ser aninhadas como argumentos Valor_se_verdadeiro e Valor_se_falso para criar testes mais elaborados (consulte o Exemplo 3 para obter um exemplo das funções SE.) Como alternativa, para testar várias condições, considere usar as funções PROC, PROCV, PROCH ou ESCOLHER. (Consulte o Exemplo 4 para obter um exemplo da função PROC.)
Se algum dos argumentos de SE for MATRIZ , cada elemento da matriz será avaliado quando a instrução SE for executada.
O Excel fornece funções adicionais que podem ser usadas para analisar os dados com base em uma condição. Por exemplo, para contar o número de ocorrências de uma cadeia de texto ou um número dentro de um intervalo de células, use as funções de planilha CONT.SE ou CONT.SES. Para calcular uma soma baseada em uma cadeia de texto ou em um número dentro de um intervalo, use as funções de planilha SOMASE ou SOMASES.

Exemplos

Copie os dados de exemplo da tabela a seguir e cole-os na célula A1 de uma nova planilha do Excel. Para as fórmulas mostrarem resultados, selecione-as, pressione F2 e pressione Enter. Se precisar, você poderá ajustar as larguras das colunas para ver todos os dados.

Dados
50	23	33175
Fórmula	Descrição	Resultado
=SE(A2<=100,"Dentro do orçamento","Acima do orçamento")	Se o número na célula A2 for menor que ou igual a 100, a fórmula retornará "Dentro do orçamento". Caso contrário, a função exibirá "Acima do orçamento".	Dentro do orçamento
=SE(A2=100,A2+B2,"")	Se o número na célula A2 for igual a 100, o valor de A2 + B2 será calculado e retornado. Caso contrário, será retornado um texto vazio ("").	0

=SE(3<1,"OK")	Se o resultado for Falso, e nenhum argumento valor_se_falso for fornecido para o resultado Falso, FALSO será retornado.	FALSO
	Se o resultado for Falso, e um argumento valor_se_falso for fornecido para esse resultado Falso (uma vírgula segue o argumento valor_se_verdadeiro), 0 será retornado.	0

Exemplo 2

Despesas Reais	Despesas Previstas
$1.500	$900
$500	$900
$500	$925
Fórmula	Descrição	Resultado
=SE(A2>B2,"Acima do Orçamento","OK")	Verifica se as despesas reais na linha 2 são maiores que as despesas previstas. Returna "Acima do Orçamento" porque o resultado do teste é Verdadeiro.	Acima do Orçamento
=SE(A3>B3,"Acima do Orçamento","OK")	Verifica se as despesas reais na linha 3 são maiores que as despesas previstas. Returna "OK" porque o resultado do teste é Falso.	OK)

Exemplo 3

Resultado
45
90
78
Fórmula	Descrição	Resultado
=SE(A2>89,"A",SE(A2>79,"B", SE(A2>69,"C",SE(A2>59,"D","F"))))	Usa condições SE aninhadas para atribuir uma nota à pontuação na célula A2.	S
=SE(A3>89,"A",SE(A3>79,"B", SE(A3>69,"C",SE(A3>59,"D","F"))))	Usa condições SE aninhadas para atribuir uma nota à pontuação na célula A3.	A
=SE(A4>89,"A",SE(A4>79,"B", SE(A4>69,"C",SE(A4>59,"D","F"))))	Usa condições SE aninhadas para atribuir uma nota à pontuação na célula A4.	C

Exemplo 4

Resultado
45
90
78
Fórmula	Descrição	Resultado
=PROC(A2, {0,60,63,67,70,73,77,80,83,87,90,93,97}, {"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})	Em vez de usar várias funções SE aninhadas, a fórmula usa a função PROC para localizar uma nota alfabética que corresponde a uma pontuação numérica armazenada em uma matriz na fórmula.	S
=PROC(A3, {0,60,63,67,70,73,77,80,83,87,90,93,97}, {"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})	Em vez de usar várias funções SE aninhadas, a fórmula usa a função PROC para localizar uma nota alfabética que corresponde a uma pontuação numérica armazenada em uma matriz na fórmula.	A-
=PROC(A4, {0,60,63,67,70,73,77,80,83,87,90,93,97}, {"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})	Em vez de usar várias funções SE aninhadas, a fórmula usa a função PROC para localizar uma nota alfabética que corresponde a uma pontuação numérica armazenada em uma matriz na fórmula.	C+