Exemplos de fórmulas comuns

Verificar se um número é maior ou menor que outro número

Use a função SE para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
15000	9000	=Coluna1>Coluna2	A Coluna1 é maior do que a Coluna2? (Sim)
15000	9000	=SE(Coluna1<=Coluna2; "OK"; "Não OK")	A Coluna1 é menor ou igual à Coluna2? (Não OK)

Retornar um valor lógico depois de comparar o conteúdo da coluna

Para um resultado que seja um valor lógico (Sim ou Não), use as funções E, OU e NÃO.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
15	9	8	=E(Coluna1>Coluna2; Coluna1<Coluna3)	15 é maior do que 9 e menor do que 8? (Não)
15	9	8	=OU(Coluna1>Coluna2; Coluna1<Coluna3)	15 é maior do que 9 ou menor do que 8? (Sim)
15	9	8	=NÃO(Coluna1+Coluna2=24)	15 mais 9 não é igual a 24? (Não)

Para um resultado que seja outro cálculo ou outro valor diferente de Sim ou Não, use as funções SE, E e OU.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
15	9	8	=SE(Coluna1=15; "OK"; "Não OK")	Se o valor na Coluna1 é igual a 15, retorna "OK". (OK)
15	9	8	=SE(E(Coluna1>Coluna2; Coluna1<Coluna3); "OK"; "Não OK")	Se 15 é maior do que 9 e menor do que 8, retorna "OK". (Não OK)
15	9	8	=SE(OU(Coluna1>Coluna2; Coluna1<Coluna3); "OK"; "Não OK")	Se 15 é maior do que 9 e menor do que 8, retorna "OK". (OK)

Exibir zeros como espaços em branco ou traços

Use a função SE para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
10	10	=Coluna1-Coluna2	Segundo número subtraído do primeiro (0)
10	10	=SE(Coluna1-Coluna2;"";Coluna1-Coluna2)	Retorna nulo quando o valor é zero (coluna em branco)
15	9	=SE(Coluna1-Coluna2;"-";Coluna1-Coluna2)	Retorna um traço quando o valor é zero (-)

Adicionar datas

Para adicionar um número de dias a uma data, use o operador de adição (+). Observe que durante a manipulação de datas, o tipo de retorno da coluna calculada deve ser definido como Data e Hora.

Coluna1	Coluna2	Fórmula	Descrição
9/6/2007	3	=Coluna1+Coluna2	Adiciona 3 dias a 9/6/2007 (12/6/2007)
10/12/2008	54	=Coluna1+Coluna2	Adiciona 54 dias a 10/12/2008 (2/2/2009)

Para adicionar um número de meses a uma data, use as funções DATA, ANO, MÊS e DIA.

Coluna1	Coluna2	Fórmula	Descrição
9/6/2007	3	=DATA(ANO(Coluna1);MÊS(Coluna1)+Coluna2;DIA(Coluna1))	Adiciona 3 meses a 9/6/2007 (9/9/2007)
10/12/2008	25	=DATA(ANO(Coluna1);MÊS(Coluna1)+Coluna2;DIA(Coluna1))	Adiciona 25 meses a 10/12/2008 (10/1/2011)

Para adicionar um número de anos a uma data, use as funções DATA, ANO, MÊS e DIA.

Coluna1	Coluna2	Fórmula	Descrição
9/6/2007	3	=DATA(ANO(Coluna1)+Coluna2;MÊS(Coluna1);DIA(Coluna1))	Adiciona 3 anos a 9/6/2007 (9/6/2010)
10/12/2008	25	=DATA(ANO(Coluna1)+Coluna2;MÊS(Coluna1);DIA(Coluna1))	Adiciona 25 anos a 10/12/08 (10/12/33)

Para adicionar uma combinação de dias, meses e anos a uma data, use as funções DATA, ANO, MÊS e DIA.

Coluna1	Fórmula	Descrição
9/6/2007	=DATA(ANO(Coluna1)+3;MÊS(Coluna1)+1;DIA(Coluna1)+5)	Adiciona 3 anos, 1 mês e 5 dias a 9/6/2007 (14/7/2010)
10/12/2008	=DATA(ANO(Coluna1)+1;MÊS(Coluna1)+7;DIA(Coluna1)+5)	Adiciona 1 ano, 7 meses e 5 dias a 9/6/2007 (14/1/2009)

Calcular a diferença entre duas datas

Use a função DATADIF para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
01-Jan-1995	15-Jun-1999	=DATADIF(Coluna1; Coluna2;"d")	Retorna o número de dias entre as duas datas (1626)
01-Jan-1995	15-Jun-1999	=DATADIF(Coluna1; Coluna2;"am")	Retorna o número de meses entre as datas, ignorando a parte do ano (5)
01-Jan-1995	15-Jun-1999	=DATADIF(Coluna1; Coluna2;"ad")	Retorna o número de dias entre as datas, ignorando a parte do ano (165)

Calcular a diferença entre dois horários

Para apresentar o resultado no formato de hora padrão (horas:minutos:segundos), use o operador de subtração (-) e a função TEXTO.

Para que esse método funcione, as horas não devem ultrapassar 24 e os minutos e segundos não devem exceder 60.

Coluna1	Coluna2	Fórmula	Descrição
09/06/2007 10:35	09/06/2007 15:30	=TEXTO(Coluna2-Coluna1;"h")	Horas entre dois horários (4)
09/06/2007 10:35	09/06/2007 15:30	=TEXTO(Coluna2-Coluna1;"h:mm")	Horas e minutos entre dois horários (4:55)
09/06/2007 10:35	09/06/2007 15:30	=TEXTO(Coluna2-Coluna1;"h:mm:ss")	Horas, minutos e segundos entre dois horários (4:55:00)

Para apresentar o resultado em um total baseado em uma unidade de tempo, use a função INT ou as funções HORA, MINUTO e SEGUNDO.

Coluna1	Coluna2	Fórmula	Descrição
09/06/2007 10:35	10/06/2007 15:30	=INT((Coluna2-Coluna1)*24)	Total de horas entre dois horários (28)
09/06/2007 10:35	10/06/2007 15:30 PM	=INT((Coluna2-Coluna1)*1440)	Total de minutos entre dois horários (1735)
09/06/2007 10:35	10/06/2007 15:30	=INT((Coluna2-Coluna1)*86400)	Total de segundos entre dois horários (104100)
09/06/2007 10:35	10/06/2007 15:30	=HORA(Coluna2-Coluna1)	Horas entre dois horários, quando a diferença não ultrapassa 24. (4)
09/06/2007 10:35	10/06/2007 15:30	=MINUTO(Coluna2-Coluna1)	Minutos entre dois horários, quando a diferença não ultrapassa 60. (55)
09/06/2007 10:35	10/06/2007 15:30	=SEGUNDO(Coluna2-Coluna1)	Segundos entre dois horários, quando a diferença não ultrapassa 60. (0)

Converter horários

Para converter horários de um formato de hora padrão em um número decimal, use a função INT.

Coluna1	Fórmula	Descrição
10:35	=(Coluna1-INT(Coluna1))*24	Número de horas desde 0:00 (10,583333)
12:15	=(Coluna1-INT(Coluna1))*24	Número de horas desde 0:00 (12,25)

Para converter horas de um número decimal no formato de hora padrão (horas:minutos:segundos), use o operador de divisão e a função TEXTO.

Coluna1	Fórmula	Descrição
10:5833	=TEXTO(Coluna1/24; "h:mm")	Horas desde 0:00 (10:35)
12:25	=TEXTO(Coluna1/24; "h:mm")	Horas desde 0:00 (12:15)

Inserir datas julianas

O termo "data juliana" às vezes é usado para se referir a um formato de data, que é uma combinação do ano atual, e o número de dias desde o início do ano. Por exemplo, 1 de janeiro de 2007 é representado como 2007001 e 31 de dezembro de 2007 é representado como 2003356.

Também há uma data juliana geralmente usada em astronomia, que é um sistema serial de data iniciado em 1º de janeiro de 4713 a.C.

Observação Esse formato não é baseado no calendário juliano.

Para converter uma data em data juliana, use as funções TEXTO e DATA.VALOR.

Coluna1	Fórmula	Descrição
23/6/2007	=TEXTO(Coluna1;"aa")&TEXTO((Coluna1-DATA.VALOR("1/1/"& TEXTO(Coluna1;"aa"))+1);"000")	Data no formato juliano, com um ano de dois dígitos (07174)
23/6/2007	=TEXTO(Coluna1;"aaaa")&TEXTO((Coluna1-DATA.VALOR("1/1/"&TEXTO(Coluna1;"aa"))+1);"000")	Data no formato juliano, com ano de quatro dígitos (2007174)

Para converter uma data em uma data juliana usada em astronomia, use a constante 2415018,50.

Essa fórmula funciona apenas para datas posteriores a 1/3/1901 e se você estiver usando o sistema de datas 1900.

Coluna1	Fórmula	Descrição
23/6/2007	=Coluna1+2415018,50	Data no formato juliano, usada em astronomia (2454274,50)

Mostrar as datas como o dia da semana

Para converter as datas no texto para o dia da semana, use as funções TEXTO e DIA.DA.SEMANA.

Coluna1	Fórmula	Descrição
19-Fev-2007	=TEXTO(DIA.DA.SEMANA(Coluna1); "dddd")	Calcula o dia da semana para a data e retorna o nome completo desse dia (segunda-feira)
3-Jan-2008	=TEXTO(DIA.DA.SEMANA(Coluna1); "ddd")	Calcula o dia da semana para a data e retorna o nome abreviado do dia (qui)

Adicionar números

Para adicionar números a duas ou mais colunas em uma linha, use o operador de adição ou a função SOMA.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
6	5	4	=Coluna1+Coluna2+Coluna3	Soma os valores nas três primeiras colunas (15)
6	5	4	=SOMA(Coluna1;Coluna2;Coluna3)	Soma os valores nas três primeiras colunas (15)
6	5	4	=SOMA(SE(Coluna1>Coluna2; Coluna1-Coluna2; 10); Coluna3)	Se Coluna1 for maior do que Coluna2, adiciona a diferença e Coluna3. Caso contrário, adiciona 10 e Coluna3. (5)

Subtrair números

Use o operador de subtração (-) para realizar essa tarefa.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
15000	9000	-8000	=Coluna1-Coluna2	Subtrai 9000 de 15000 (6000)
15000	9000	-8000	=SOMA(Coluna1; Coluna2; Coluna3)	Adiciona números nas três primeiras colunas, incluindo valores negativos (16000)

Calcular a diferença entre dois números como um percentual

Use os operadores de subtração (-) e divisão (/), além da função ABS.

Coluna1	Coluna2	Fórmula	Descrição
2342	2500	=(Coluna2-Coluna1)/ABS(Coluna1)	Alteração percentual (6,75% ou 0,06746)

Multiplicar números

Use o operador de multiplicação (*) ou a função MULT para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
5	2	=Coluna1*Coluna2	Multiplica os números nas duas primeiras colunas (10)
5	2	=MULT(Coluna1; Coluna2)	Multiplica os números nas duas primeiras colunas (10)
5	2	=MULT(Coluna1;Coluna2;2)	Multiplica os números nas duas primeiras colunas e o número 2 (20)

Dividir números

Use o operador de divisão (/) para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
15000	12	=Coluna1/Coluna2	Divide 15000 por 12 (1250)
15000	12	=(Coluna1+10000)/Coluna2	Adiciona 15000 e 9000 e divide o total por 12 (2000)

Calcular a média de números

A média também é chamada mediana. Para calcular a média dos números em duas ou mais colunas de uma linha, use a função MÉDIA.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
6	5	4	=MÉDIA(Coluna1; Coluna2;Coluna3)	Média dos números nas três primeiras colunas (5)
6	5	4	=MÉDIA(SE(Coluna1>Coluna2; Coluna1-Coluna2; 10); Coluna3)	Se Coluna1 for maior do que Coluna, calcular a média da diferença e Coluna3. Caso contrário, calcular a média do valor 10 e Coluna3. (2,5)

Calcular a mediana de números

A mediana é o valor no centro de um intervalo ordenado de números. Use a função MED para calcular a mediana de um grupo de números.

A	B	C	D	E	F	Fórmula	Descrição
10	7	9	27	0	4	=MED(A; B; C; D; E; F)	Mediana dos números nas 6 primeiras colunas (8)

Calcular o menor ou o maior número em um intervalo

Para calcular o menor ou o maior número em duas ou mais colunas em uma linha, use as funções MÍNIMO e MÁXIMO.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
10	7	9	=MÍNIMO(Coluna1; Coluna2; Coluna3)	Número menor (7)
10	7	9	=MÁXIMO(Coluna1; Coluna2; Coluna3)	Número maior (10)

Contar valores

Para contar valores numéricos, use a função CONT.NÚM.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
Maçã		12/12/2007	=CONT.NÚM(Coluna1; Coluna2; Coluna3)	Conta o número de colunas que contêm valores numéricos, incluindo valores de data e hora. Exclui texto e valores nulos. (1)
R$ 12	#DIV/0!	1,01	=CONT.NÚM(Coluna1; Coluna2; Coluna3)	Conta o número de colunas que contêm valores numéricos, mas exclui valores lógicos e de erro (2)

Aumentar ou diminuir um número em um percentual

Use o operador de percentual (%) para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
23	3%	=Coluna1*(1+5%)	Aumenta o número na Coluna1 em 5% (24,15)
23	3%	=Coluna1*(1+Coluna2)	Aumenta o número na Coluna1 com o valor percentual na Coluna2: 3% (23,69)
23	3%	=Coluna1*(1-Coluna2)	Diminui o número na Coluna1 com o valor percentual na Coluna2: 3% (22,31)

Elevar um número a uma potência

Use o operador exponencial (^) ou a função POTÊNCIA para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
5	2	=Coluna1^Coluna2	Calcula cinco ao quadrado (25)
5	3	=POTÊNCIA(Coluna1; Coluna2)	Calcula cinco ao cubo (125)

Arredondar um número

Para arredondar um número, use as funções ARREDONDAR.PARA.CIMA, ÍMPAR e PAR.

Coluna1	Fórmula	Descrição
20,3	=ARREDONDAR.PARA.CIMA(Coluna1;0)	Arredonda 20,3 para cima, para o número inteiro mais próximo (21)
-5,9	=ARREDONDAR.PARA.CIMA(Coluna1;0)	Arredonda -5,9 para cima (-6)
12,5493	=ARREDONDAR.PARA.CIMA(Coluna1;2)	Arredonda 12,5493 para cima, para o centésimo mais próximo, duas casas decimais (12,55)
20,3	=PAR(Coluna1)	Arredonda 20,3 para cima, para o número par mais próximo (22)
20,3	=ÍMPAR(Coluna1)	Arredonda 20,3 para cima, para o número ímpar mais próximo (21)

Para arredondar um número para baixo, use a função ARREDONDAR.PARA.BAIXO.

Coluna1	Fórmula	Descrição
20,3	=ARREDONDAR.PARA.BAIXO(Coluna1;0)	Arredonda 20,3 para baixo, para o número inteiro mais próximo (20)
-5,9	=ARREDONDAR.PARA.BAIXO(Coluna1;0)	Arredonda -5,9 para baixo (-5)
12,5493	=ARREDONDAR.PARA.BAIXO(Coluna1;2)	Arredonda 12,5493 para baixo, para o centésimo mais próximo, duas casas decimais (12,54)

Para arredondar um número para o número ou fração mais próximos, use a função ARRED.

Coluna1	Fórmula	Descrição
20,3	=ARRED(Coluna1;0)	Arredonda 20,3 para baixo, porque a parte fracionária é menor do que 0,5 (20)
5,9	=ARRED(Coluna1;0)	Arredonda 5,9 para cima, porque a parte fracionária é maior do que 0,5 (6)
-5,9	=ARRED(Coluna1;0)	Arredonda -5,9 para baixo, porque a parte fracionária é menor do que 0,5 (-6)
1,25	=ARRED(Coluna1; 1)	Arredonda o número para o décimo mais próximo (uma casa decimal). Como a parte a ser arredondada é 0,05 ou maior, o número é arredondado para cima (resultado: 1,3)
30,452	=ARRED(Coluna1; 2)	Arredonda o número para o centésimo mais próximo (duas casas decimais). Como a parte a ser arredondada, 0,002, é menor do que 0,005, o número é arredondado para baixo (resultado: 30,45)

Para arredondar um número para o dígito significativo acima de 0, use as funções ARRED, ARREDONDAR.PARA.CIMA, ARREDONDAR.PARA.BAIXO, INT e NÚM.CARACT.

Coluna1	Fórmula	Descrição
5492820	=ARRED(Coluna1;3-NÚM.CARACT(INT(Coluna1)))	Arredonda o número para 3 dígitos significativos (5490000)
22230	=ARREDONDAR.PARA.BAIXO(Coluna1;3-NÚM.CARACT(INT(Coluna1)))	Arredonda o número inferior para baixo, para 3 dígitos significativos (22200)
5492820	=ARREDONDAR.PARA.CIMA(Coluna1; 5-NÚM.CARACT(INT(Coluna1)))	Arredonda o número superior para cima, para 5 dígitos significativos (5492900)

Alterar maiúsculas e minúsculas do texto

Use as funções MAIÚSCULA, MINÚSCULA ou PRI.MAIÚSCULA para realizar essa tarefa.

Coluna1	Fórmula	Descrição
janeth Esteves	=MAIÚSCULA(Coluna1)	Altera o texto para maiúsculas (JANETH ESTEVES)
janeth Esteves	=MINÚSCULA(Coluna1)	Altera o texto para minúsculas (janeth esteves)
janeth Esteves	=PRI.MAIÚSCULA(Coluna1)	Altera o texto para a primeira letra de cada palavra em maiúsculas (Janeth Esteves)

Combinar nome e sobrenome

Use o operador E comercial (&) ou a função CONCATENAR para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
Paula	Mattos	=Coluna1&Coluna2	Combina as duas cadeias de caracteres (PaulaMattos)
Paula	Mattos	=Coluna1&" "&Coluna2	Combina as duas cadeias de caracteres, separadas por um espaço (Paula Mattos)
Paula	Mattos	=Coluna2&","&Coluna1	Combina as duas cadeias de caracteres, separadas por vírgula (Mattos, Paula)
Paula	Mattos	=CONCATENAR(Coluna2; ","; Coluna1)	Combina as duas cadeias de caracteres, separadas por uma vírgula (Mattos,Paula)

Combinar texto e números de colunas diferentes

Use as funções CONCATENAR e TEXTO e o operador E comercial (&) para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
Saraiva	28	=Coluna1&" vendeu "&Coluna2&" unidades."	Combina o conteúdo acima em uma frase (Saraiva vendeu 28 unidades)
Camargo	40%	=Coluna1&" vendeu "&TEXTO(Coluna2;"0%")&" do total de vendas."	Combina o conteúdo acima em uma frase (Camargo vendeu 40% do total de vendas). Observação A função TEXTO anexa o valor formatado da Coluna2, em vez do valor de base, que é 0,4.
Saraiva	28	=CONCATENAR(Coluna1;" vendeu ";Coluna2;" unidades.")	Combina o conteúdo acima em uma frase (Saraiva vendeu 28 unidades)

Combinar texto com uma data ou hora

Use a função TEXTO e o operador E comercial (&) para realizar essa tarefa.

Coluna1	Coluna2	Fórmula	Descrição
Data da Cobrança	5-Jun-2007	="Data da instrução: "&TEXTO(Coluna2; "d-mmm-aaaa")	Combina texto com uma data (Data da instrução: 5-Jun-2007)
Data da Cobrança	5-Jun-2007	=Coluna1&" "&TEXTO(Coluna2; "mmm-dd-aaaa")	Combina texto e data de colunas diferentes em uma coluna (Data da Cobrança 05-Jun-2007)

Comparar o conteúdo das colunas

Para comparar uma coluna com outra ou com uma lista de valores, use as funções EXATO e OU.

Coluna1	Coluna2	Fórmula	Descrição
BD122	BD123	=EXATO(Coluna1;Coluna2)	Compara o conteúdo das duas primeiras colunas (Não)
BD122	BD123	=EXATO(Coluna1; "BD122")	Compara o conteúdo da Coluna1 e da sequência de caracteres "BD122" (Sim)
BD122	BD123	=OU(EXATO("BD121"; Coluna1; Coluna2)	Compara a cadeia de caracteres "BD121" com o conteúdo das duas primeiras colunas (Não)

Verifica se o valor da coluna ou de parte da coluna corresponde a um texto específico

Para verificar se o valor de uma coluna ou parte dela corresponde a um texto específico, use as funções SE, PROCURAR, LOCALIZAR e ÉNÚM.

Coluna1	Fórmula	Descrição
Esteves	=SE(Coluna1="Esteves"; "OK"; "Não OK")	Verifica se a Coluna1 é Esteves (OK)
Esteves	=SE(ÉNÚM(PROCURAR("v";Coluna1)); "OK"; "Não OK")	Verifica se a Coluna1 contém a letra v (OK)
BD123	=ÉNÚM(PROCURAR("BD";Coluna1))	Verifica se a Coluna1 contém BD (Sim)

Contar colunas que não estão vazias

Use a função CONT.VALORES para realizar essa tarefa.

Coluna1	Coluna2	Coluna3	Fórmula	Descrição
Vendas	19		=CONT.VALORES(Coluna1; Coluna2)	Conta o número de colunas que não estão vazias (2)
Vendas	19		=CONT.VALORES(Coluna1; Coluna2; Coluna3)	Conta o número de colunas que não estão vazias (2)

Remover caracteres do texto

Use as funções NÚM.CARACT, ESQUERDA e DIREITA para realizar essa tarefa.

Coluna1	Fórmula	Descrição
Vitamina A	=ESQUERDA(Coluna1;NÚM.CARACT(Coluna1)-2)	Retorna 7 (9-2) caracteres, a partir da esquerda (Vitamina)
Vitamina B1	=DIREITA(Coluna1; NÚM.CARACT(Coluna1)-8)	Retorna 2 (10-8) caracteres, a partir da direita (B1)

Remover espaços do início e do fim da coluna

Use a função ARRUMAR para realizar essa tarefa.

Coluna1	Fórmula	Descrição
Olá!	=ARRUMAR(Coluna1)	Remove os espaços do início e do fim (Olá!)

Repetir um caractere em uma coluna

Use a função REPT para realizar essa tarefa.

Fórmula	Descrição
=REPT(".";3)	Repete um ponto 3 vezes (...)
=REPT("-";10)	Repete um traço 10 vezes (----------)

Ocultar valores de erro em colunas

Para mostrar um traço, #N/D ou ND no lugar de um valor de erro, use a função ÉERROS.

Coluna1	Fórmula	Descrição
10	=Coluna1/Coluna2	Resulta em um erro (#DIV/0)
10	=SE(ÉERROS(Coluna1/Coluna2);"ND";Coluna1/Coluna2)	Retorna ND quando o valor é um erro
10	=SE(ÉERROS(Coluna1/Coluna2);"-";Coluna1/Coluna2)	Retorna um traço quando o valor é um erro

Fórmulas condicionais

Fórmulas de data e hora

Fórmulas matemáticas

Fórmulas de texto

Outras fórmulas